Brettb.Com
  HOME | ABOUT ME | BIOTECHNOLOGY | ARTICLES | GALLERY | CONTACT
Search: Go
TECHNICAL ARTICLES
 ASP
 ASP.NET
 JavaScript
 Transact SQL
 Other Articles
 Software Reviews

PHOTO GALLERIES
 Canon EOS 300D Samples
 Akihabara Maids!
 More Galleries...

TRAVEL LOG
 2009: China
 2008: Tokyo
 2007: Tokyo
 2006: Hong Kong
 2005: New York City

MORE STUFF
 Search Engine Optimisation
 Build an ASP Search Engine
 My Tropical Fishtank
 Autoglass
 SQL Month Name
 SQL Get Date Today
 SQL Year Month
 Other New Stuff...

POPULAR STUFF
 Regular Expressions
 Index Server & ASP
 JavaScript Ad Rotator

Home > Articles

Searching Indexing Service With ASP

Indexing Service makes it very straightforward to create search solutions that would cost many thousands of dollars to implement using alternative technologies.

This article describes what is required to use Indexing Service from within ASP. It assumes you have access to a web server running Internet Information Services in a Microsoft Windows environment.

Creating a search form

The first thing to do is to create a page containing a form in which the user can enter their search word or phrase. You can of course have a combined search form page and search results page, but I prefer to keep them separate. An example search form is shown below. This code should be saved as SearchForm.asp:

<form method="POST" action="SearchResults.asp" name="frmSearch">
<p>
<input type="text" maxlength="255" name="query" size="20" value>
<input type="submit" value="Search" name="B1">
</p>
</form>

As you can see from this HTML, it is a simple form that will post a single text field called query to the page called SearchResults.asp.

Creating a search results page

The following code can be used for a basic search results page. It should be saved as SearchResults.asp.

The first part of the search results page initialises variables and constants:

<%
Dim sSearchString
Dim oQuery

sSearchString = Request.Form("query")

Const SEARCH_CATALOG = "
catalog_name"
%>

The search string was posted from the SearchForm.asp search form page, and the word or phrase to be searched for are extracted from the query item in the Request.Form collection.

The SEARCH_CATALOG constant is also defined. This name will vary so you will have to change it. If your site is hosted with a hosting company then they will usually set up a catalog on the Indexing Service for you, then let you know the name of your search catalog. If you are using your own web server, then you should be able to determine the catalog name from the Indexing Service Management Console. Describing how to set up and use Indexing Service catalogs is beyond the scope of this article.

The next part of the search results page initialises the Indexing Service Query COM component which enables the search to be performed:

<%
Set oQuery = Server.CreateObject("IXSSO.Query")

oQuery.Catalog = SEARCH_CATALOG
oQuery.Query = "@all " & sSearchString & " AND NOT #path *_* AND NOT #path *downloads* AND NOT #path *images* AND NOT #filename *.class AND NOT #filename *.asa AND NOT #filename *.css AND NOT #filename *postinfo.html"
oQuery.MaxRecords = 200
oQuery.SortBy = "rank[d]"
oQuery.Columns = "DocAuthor, vpath, doctitle, FileName, Path, Write, Size, Rank, Create, Characterization, DocCategory"

Set oRS = oQuery.CreateRecordSet("nonsequential")
%>

Further details of the Query object’s methods and properties are to be found in the IIS 4.0 online documentation. The properties of the object set in the sample code above are as follows:

  • Catalog: The name of the search catalog to be searched.
  • Query: The query to be made. Note that the query in this example is comprised of the search string, plus a list of file and folder exclusions. It is important to remember that Indexing Service indexes content by using the file system, and therefore is able to index files you’d rather not allow users to search from the web. Examples include global.asa files, FrontPage configuration files (these folders have underscores in their names) and files such as Java class files and Cascading Style Sheets.
  • MaxRecords: This property specifies the maximum number of search results that should be returned.
  • SortBy: This specifies which column name the search results should sorted by. The usual setting for this is rank[d], i.e. sort results in descending order according to their similarilty to the search string.
  • Columns: A list of column properties that should be returned in the search results. These will be discussed in further detail later on.

Finally, an ADO RecordSet is created from the records found for this search. The neat thing about Indexing Service is that the returned RecordSet of search results can be used in an almost identical fashion to RecordSets returned from databases. A list of results is, therefore, displayed simply by looping through this RecordSet and displaying fields from the RecordSet:

<%
If oRS.EOF Then
Response.Write "No pages were found for the query <i>" & sSearchString & "</i>"
Else
Do While Not oRS.EOF

Response.write "<b>FileName:</b> " & oRS("FileName") & "<br>"
Response.write "<b>doctitle:</b> " & oRS("doctitle") & "<br>"
Response.write "<b>Size:</b> " & oRS("Size") & "<br>"
Response.write "<b>Create:</b> " & oRS("Create") & "<br>"
Response.write "<b>Write:</b> " & oRS("Write") & "<br>"
Response.write "<b>Characterization:</b> " & oRS("Characterization") & "<hr>"

oRS.MoveNext
Loop
End If
%>

This code loops through the records corresponding to the matching documents found and displays some of the properties of each document. This is where the columns property of the Indexing Service Query are used: these specify the column names that are returned for each record. In the sample code above, FileName refers to the record’s name on disk.

doctitle corresponds to the document’s title (i.e. <title> tag if the document is HTML). Size is the size in bytes of the file on disk. Create is the date and time the document was created, whereas Write is the date and time the document was modified. Finally, Characterization is a summary of the document. The summary corresponds to the Description meta tag in HTML files, so it is worthwhile putting this tag into documents. If the Description tag isn’t present, Indexing Service will display the first one or two sentences from the document.

Unfortunately the FileName property only contains the file's name in lower case. This can lead to problems if you are building a cross-platform search solution with operating systems that use case sensitive filenames (e.g. Unix and Linux).

Finally at the bottom of the page the objects are released:

<%
Set oRS = nothing
Set oQuery = nothing
%>

An example screenshot of the search results page is below as described above, the page displays the FileName, doctitle, Size, Create and Characterization for each matching document:

Output from SearchResults.asp

As you can see the page is fairly basic, so a few cosmetic improvements would be required if the page was to be used on a production website. Further suggestions for improving the display of search results are in the article "More about Searching Indexing Service With ASP".

Code samples and working ASP pages

  • Fully working versions of the search form and results pages described in this article may be accessed from this website.
  Site Map | Privacy Policy

All content is 1995 - 2012