Brettb.Com
  HOME | ABOUT ME | BIOTECHNOLOGY | ARTICLES | GALLERY | CONTACT
Search: Go
TECHNICAL ARTICLES
 ASP
 ASP.NET
 JavaScript
 Transact SQL
 Other Articles
 Software Reviews

PHOTO GALLERIES
 Canon EOS 300D Samples
 Akihabara Maids!
 More Galleries...

TRAVEL LOG
 2009: China
 2008: Tokyo
 2007: Tokyo
 2006: Hong Kong
 2005: New York City

MORE STUFF
 Search Engine Optimisation
 Build an ASP Search Engine
 My Tropical Fishtank
 Autoglass
 SQL Month Name
 SQL Get Date Today
 SQL Year Month
 Other New Stuff...

POPULAR STUFF
 Regular Expressions
 Index Server & ASP
 JavaScript Ad Rotator

Home > Articles

Improving ASP Performance With Data Caching

One of the nicest features of ASP.NET is the ability to cache page content. This can be used to substantially reduce load on a website's database - which is an obvious attraction if the site uses Microsoft's Access to store data rather than SQL Server.

Unfortunately there is no built in caching system in classic ASP, but it is easy to build one by using the Application object to store data. As such the techniques described in this article can be used to bring useful performance enhancements to legacy websites where upgrading the database or porting the code to ASP.NET is not a viable option.

An Example of ASP Data Caching

In this example, an e-commerce website contains a list of popular products visible in a box displayed on all of the pages within the site. Since the website only takes 2 - 3 orders a day, the list of popular products does not need to be constantly updated. There are three application variables required in the Application_OnStart subroutine of the global.asa file:

Application("CachingDuration") = 120
Application("PopularProductsHTML") = ""
Application("PopularProductsHTML.LastModified") = Now()

The CachingDuration application variable specifies the number of minutes that the website's cached content should be stored for. The PopularProductsHTML application variable stores the actual HTML for the popular products table. Finally, the PopularProductsHTML.LastModified application variable stores the date and time the popular products HTML was last retrieved from the database. The ASP code for retrieving the popular products from the database is containing within the function GetPopularProductsHTML. There is a single argument - the number of popular products to return:

<%
Function GetPopularProductsHTML(NumberOfProducts)

    On Error Resume Next
    Dim DataConnection
    Dim RecordSet
    Dim SQL
    Dim ReturnString
    Dim ProductName
    Dim NumberOfProductsDisplayed
    
    'Access Query for returning popular products
    SQL = "sp_GetPopularProducts"

    Set DataConnection = Server.CreateObject("ADODB.connection")
    DataConnection.Open Application("ConnectionString")
    
    Set RecordSet = Server.CreateObject("ADODB.Recordset")

    RecordSet.Open SQL, DataConnection
    
    NumberOfProductsDisplayed = 0
    
    Do While Not RecordSet.EOF
    
            If NumberOfProductsDisplayed < NumberOfProducts Then

                ProductName = Replace(RecordSet("ProductName"), Chr(34), "'")
                ReturnString = ReturnString & "<a href=ViewProduct.asp?Product="" & RecordSet("ProductID") & """>" & ProductName & "</a><br>"

            End If
        
            NumberOfProductsDisplayed = NumberOfProductsDisplayed + 1
    
        RecordSet.MoveNext
        
    Loop
    
    RecordSet.Close
    Set RecordSet = nothing
    DataConnection.Close
    Set DataConnection = nothing
    
    GetPopularProductsHTML = ReturnString

End Function
%>

This function is called from the ASP VBScript shown below that builds the popular products table. This code also checks that the cached HTML has not expired; if it has expired then the data is retrieved from the database.

<%
Dim PopularProductsBoxTitleText
Dim PopularProductsBoxContentsText
Dim NumberOfProducts

PopularProductsBoxTitleText = "Popular Products"
NumberOfProducts = 25

'If cache is empty then retrieve data from the database
If Application("PopularProductsHTML") = "" Then

    PopularProductsBoxContentsText = GetPopularProductsHTML(NumberOfProducts)
    
    Application.Lock()
    Application("PopularProductsHTML") = PopularProductsBoxContentsText
    Application("PopularProductsHTML.LastModified") = Now()
    Application.UnLock()
    
'Retrieve content directly from the cache instead of the database
Else
    PopularProductsBoxContentsText = Application("PopularProductsHTML")
    
    'Is the cache out of date? If so retrieve the content from the database and store in the cache
    'The VBScript DateDiff function can be used to compare dates (n = comparisons of minutes)
    If DateDiff("n", Application("PopularProductsHTML.LastModified"), Now()) > Application("CachingDuration") Then
        Response.Write("<!--Cache Updated-->") 'Useful debugging line - remove from production code
        PopularProductsBoxContentsText = GetPopularProductsHTML(NumberOfProducts)

        'Store the content in the Application variables.
        Application.Lock()
            Application("PopularProductsHTML") = PopularProductsBoxContentsText
            Application("PopularProductsHTML.LastModified") = Now()
        Application.UnLock()

    End If    

End If

'Display the popular products box
If PopularProductsBoxContentsText <> "" Then
%>
    <div class="BoxOutline">
        <div class="BoxTitle">
            <span class="PopularProductsBoxTitleText"><%=PopularProductsBoxTitleText%></span>
        </div>
        <div class="BoxContents">
            <span class="PopularProductsBoxContentsText">
                <%=PopularProductsBoxContentsText%>
            </span>
        </div>
    </div>
<%
End If
%>

Don't forget that content stored in Application variables are shared by all users of the site, so if updating Application variables the Lock() method should be called to prevent more than one client from modifying the same Application variable simultaneously. Remember to use the Unlock() method afterwards!

When to use ASP Caching

Caching is most useful for data that changes - but not too often. For example an e-commerce store could display a list of popular products, or an information site could display a list of press releases. If you have several regions of this information on the same page then the performance increase from caching could be substantial.

Don't forget that it is also possible to build functionality into the admin part of the site so that the cache would be flushed if new content is added to the database. That way the website administrator would not have to wait until the cache timed out in order for new content to appear on the website.

Remember that data stored in Application variables is visible by all the users of the website, so if your site uses extensive personalisation features you may be better off caching data in the Session object.

Links

  • The ASP Documentation Tool can automatically document your ASP (VBScript and JScript) websites - why not give it a go?
  Site Map | Privacy Policy

All content is 1995 - 2012